Network ICN_Network

The ICN Simulation Ground

This simulation ground implements a publish subscribe network. The main component is the PSRouter, which forwards the published messages towards the proper destination. All the pub-sub functionality is incorporated inside the Topology Manager. The general topology is created in the initialization phase and it is random, according to the random seeds given in the ini file of the simulation.

See also: PSRouter, PubHost, SubHost, TMInterface, IITable

Author: Nikolaos Vastardis

Parameters:

Properties:

Unassigned submodule parameters:

Source code:

//
// <b> The ICN Simulation Ground </b>
//
// This simulation ground implements a publish subscribe network. The main
// component is the PSRouter, which forwards the published messages towards
// the proper destination. All the pub-sub functionality is incorporated
// inside the Topology Manager. The general topology is created in the 
// initialization phase and it is random, according to the random seeds
// given in the ini file of the simulation. 
// 
// @see PSRouter, PubHost, SubHost, TMInterface, IITable
//
// @author Nikolaos Vastardis
//
network ICN_Network
{
    parameters:
        int numRouters;
        int numPubs;
        int numSubs;
        double connectedness; //0.0<x<1.0 
        int Datarate @unit(Mbps);
        double PubSubProportion = default(0.5);
        string TopManager = default("TMBoostLA");
        bool FP_check = default(false);
        @display("bgb=756,491;i=old/earth1");
    types:
        channel G extends ned.DatarateChannel
        {
            datarate = 1Gbps;
        }
        channel E extends ned.DatarateChannel
        {
            datarate = 10Mbps;
            delay = 450us;
        }
    submodules:
        psRouter[numRouters]: PSRouter;
        Publisher[numPubs]: PubHost;
        Subscriber[numSubs]: SubHost;
        iiTable: IITable {
            @display("p=31,373");
        }
        tm: <TopManager> like TMInterface {
            @display("p=31,304");
        }
    connections allowunconnected:
        for i=0..numRouters-1, for j=0..numRouters-1, if i<j && (j==i+1 || uniform(0,1) < connectedness) {
            psRouter[i].ethg++ <--> E <--> psRouter[j].ethg++;
        }
        for i=0..numPubs-1 {
            psRouter[intuniform(0,numRouters-1)].ethg++ <--> G <--> Publisher[i].ethg++;
        }
        for i=0..numSubs-1 {
            psRouter[intuniform(0,numRouters-1)].ethg++ <--> G <--> Subscriber[i].ethg++;
        }
}

This documentation is released under the Creative Commons license